Arduinoと ATtiny2313で SPI

• Arduinoをマスター、AVR ATtiny2313Vをスレーブとする。
• ATtiny2313にはSSがないみたいなので、PB4をLOWにしたらスレーブ選択、という体（てい）で。
• マスターから送ったデータ8ビットを、スレーブ側でLED点灯で表現（面倒だったのでLEDは4つ。下位4ビットだけ・・・）＆前回データを反転したものをマスターに返すことで、通信がうまくいったことを確認する。Arduino側はスレーブから受け取ったデータをSerialに書きだす。

#include <SPI.h>
#include <util/delay.h>

void setup()
{
  Serial.begin(9600);

  SPI.begin();
  SPI.setBitOrder(MSBFIRST);
  SPI.setClockDivider(SPI_CLOCK_DIV8);
  SPI.setDataMode(SPI_MODE0);

  pinMode(2, OUTPUT);
  digitalWrite(2, HIGH);

  uint8_t d = 0;
  for (;;)
  {
    digitalWrite(2, LOW);
    uint8_t a = SPI.transfer(d);
    digitalWrite(2, HIGH);
  
    Serial.print(d, HEX);
    Serial.write(", ");
    Serial.println(a, HEX);
    d++;
    _delay_ms(300);
  }
}


void loop()
{
}

#include <avr/interrupt.h>
#include <avr/io.h>
#include <util/delay.h>


#define	USCK	PB7
#define	MOSI	PB5
#define	MISO	PB6	


volatile uint8_t triggered = 0;

ISR(PCINT_vect)
{
	if (!bit_is_set(PINB, 4))
	{
		triggered = 1;
	}
}

uint8_t	spi_slave_receive(uint8_t send)
{
	USIDR = send;
	USISR = (1<<USIOIF);
	while (!(USISR & (1<<USIOIF)));
	uint8_t	receive = USIDR;

	return	receive;
}

void	spi_slave_init()
{
	USICR = (1<<USIWM0)|(1<<USICS1);

	// MISO(PB6)は出力に
	DDRB |= _BV(MISO);
	// MOSI(PB5)/USCKは入力に
	DDRB &= ~(_BV(MOSI) | _BV(USCK));

	// MOSI(PB5)/USCK(PB7)プルアップ
	PORTB |= (_BV(MOSI) | _BV(USCK));
}

int main(void) 
{
	spi_slave_init();

	// LED(PB0..PB3)は出力に
	DDRB |= _BV(PB0) | _BV(PB1) | _BV(PB2) | _BV(PB3);

	// LEDを消灯
	PORTB &= ~(_BV(PB0) | _BV(PB1) | _BV(PB2) | _BV(PB3));

	// PB4プルアップ
	PORTB |= _BV(PB4);

	// PB4の変化割込み
	GIMSK |= _BV(PCIE);
	PCMSK |= _BV(PB4);

	sei();

	uint8_t  d = 0x00;
	for (;;)
	{
		while (!triggered)
		{
		}

		// PB4がLOWになった

		// clear
		triggered = 0;


		// 1バイト受信＋送信
		d = spi_slave_receive(~d);


		// display bits as LED
		for (int i = 0, check = 1; i < 4; i++, check*=2)
		{
			if (d & check)
			{
				PORTB |= check;
			}
			else
			{
				PORTB &= ~(check);
			}
		}
	}
}